*
* beauty - duet between Gaina and George in
* 484 frames (padded out to 512)
*
***********************************************
*
figure stage 4 floor right left back
*
ellipsoid floor 2000 5 2000
ellipsoid back 2000 2000 5
ellipsoid right 5 2000 2000
ellipsoid left 5 2000 2000
*
joint crack floor 0 0 2050 back 0 -1000 0
joint lwing floor -470 0 2000 left 0 0 2000
joint rwing floor +470 0 2000 right 0 0 2000
*
linear 0 1 colour floor 255 255 0
linear 0 1 colour back 0 0 255
linear 0 1 colour left 0 0 0
linear 0 1 colour right 0 0 0
*
linear 0 1 moveto stage floor 500 -5 0
linear 0 1 rotate left lwing 2
linear 0 1 rotate right rwing 2
*
***********************************************
*
* george (by Bruce Morgan)
*
figure george 37 *
gltoes grtoes glfoot grfoot glleg grleg glthigh grthigh *
gluarm gruarm glmarm grmarm gllarm grlarm glhand grhand *
glthumb grthumb glfinger grfinger glear grear gleye greye *
gpelvis gchest glchest grchest gshldrs gneck ghead *
gbhead gforred glonose gunose glojaw gujaw
*
ellipsoid gltoes 6 3 5
ellipsoid grtoes 6 3 5
ellipsoid glfoot 7 4 8
ellipsoid grfoot 3 4 8
ellipsoid glleg 9 18 10
ellipsoid grleg 9 18 10
ellipsoid glthigh 15 30 16
ellipsoid grthigh 15 30 16
*
ellipsoid gluarm 11 24 15
ellipsoid gruarm 11 24 15
ellipsoid glmarm 9 24 12
ellipsoid grmarm 9 24 12
ellipsoid gllarm 6 13 6
ellipsoid grlarm 6 13 6
ellipsoid glhand 7 9 4
ellipsoid grhand 7 9 4
ellipsoid glthumb 2 5 2
ellipsoid grthumb 2 5 2
ellipsoid glfinger 6 6 3
ellipsoid grfinger 6 6 3
*
ellipsoid glear 0.1 3 2
ellipsoid grear 0.1 3 2
ellipsoid gleye 2 1 .4
ellipsoid greye 2 1 .4
*
ellipsoid gpelvis 33 38 24
ellipsoid gchest 36 36 23
ellipsoid glchest 20 20 10
ellipsoid grchest 20 20 10
ellipsoid gshldrs 44 22 22
ellipsoid gneck 1 2 3
ellipsoid ghead 14 18 10
*
ellipsoid gbhead 14 18 9
ellipsoid gforred 10 3 7
ellipsoid glonose 5 2 2
ellipsoid gunose 4 4 1
ellipsoid glojaw 8 3 8
ellipsoid gujaw 8 3 8
*
joint gthorax gshldrs 0 0 0 gchest 0 14 1
joint gwaist gchest 0 -24 5 gpelvis 0 0 0
joint glchst gshldrs +19 0 15 glchest 0 0 0
joint grchst gshldrs -19 0 15 grchest 0 0 0
*
joint glshldr gshldrs -31 3 8 gluarm 8 22 6
joint glelbow gluarm 0 -20 0 gllarm 0 33 4
joint glfrarm glmarm 0 -14 0 gllarm 0 3 0
joint glwrist gllarm -2 -10 0 glhand 0 8 0
joint glknkle glhand 1 -6 0 glfinger 0 3 0
joint glpalm glhand -5 2 3 glthumb 0 4 0
*
joint grshldr gshldrs 31 3 8 gruarm -8 22 6
joint grelbow gruarm 0 -20 0 grlarm 0 33 4
joint grfrarm grmarm 0 -14 0 grlarm 0 3 0
joint grwrist grlarm +2 -10 0 grhand 0 8 0
joint grknkle grhand -1 -6 0 grfinger 0 3 0
joint grpalm grhand 5 2 3 grthumb 0 4 0
*
joint glhip gpelvis -10 -13 4 glthigh 0 21 0
joint glknee glthigh 0 -26 0 glleg 0 15 0
joint glankle glleg 0 -17 0 glfoot 0 1 -5
joint glfnkle glfoot 1 -1 6 gltoes 0 0 -2
*
joint grhip gpelvis +10 -13 4 grthigh 0 21 0
joint grknee grthigh 0 -26 0 grleg 0 15 0
joint grankle grleg 0 -17 0 grfoot 0 1 -5
joint grfnkle grfoot -1 -1 6 grtoes 0 0 -2
*
joint gspine gshldrs 0 18 0 gneck 0 0 0
joint gthroat gneck 0 0 0 ghead 0 -14 -7
*
joint gskull ghead 0 0 -6 gbhead 0 0 3
joint gbrow ghead 0 4 7 gforred 0 0 0
joint gjlear ghead 14 0 -4 glear 0 0 0
joint gjrear ghead -14 0 -4 grear 0 0 0
joint gnose ghead 0 -4 10 gunose 0 0 0
joint gface gunose 0 -2 0 glonose 0 0 0
joint gumouth ghead 0 -6 0 gujaw 0 0 -8
joint glomth ghead 0 -13 0 glojaw 0 0 -6
joint glsokt ghead 4 0 10 gleye 0 0 0
joint grsokt gleye -8 0 0 greye 0 0 0
*
linear 0 1 colour gltoes 64 32 0
linear 0 1 colour grtoes 64 32 0
linear 0 1 colour glfoot 64 32 0
linear 0 1 colour grfoot 64 32 0
linear 0 1 colour glleg 64 32 0
linear 0 1 colour grleg 64 32 0
linear 0 1 colour glthigh 64 32 0
linear 0 1 colour grthigh 64 32 0
*
linear 0 1 colour gluarm 64 32 0
linear 0 1 colour gruarm 64 32 0
linear 0 1 colour glmarm 64 32 0
linear 0 1 colour grmarm 64 32 0
linear 0 1 colour gllarm 64 32 0
linear 0 1 colour grlarm 64 32 0
linear 0 1 colour glhand 64 32 0
linear 0 1 colour grhand 64 32 0
linear 0 1 colour glthumb 64 32 0
linear 0 1 colour grthumb 64 32 0
linear 0 1 colour glfinger 64 32 0
linear 0 1 colour grfinger 64 32 0
*
linear 0 1 colour glear 64 32 0
linear 0 1 colour grear 64 32 0
linear 0 1 colour gleye 0 255 0
linear 0 1 colour greye 0 255 0
*
linear 0 1 colour gpelvis 64 32 0
linear 0 1 colour gchest 64 32 0
linear 0 1 colour glchest 64 32 0
linear 0 1 colour grchest 64 32 0
linear 0 1 colour gshldrs 64 32 0
linear 0 1 colour gneck 64 32 0
linear 0 1 colour ghead 64 32 0
*
linear 0 1 colour gbhead 64 32 0
linear 0 1 colour gforred 64 32 0
linear 0 1 colour glonose 64 32 0
linear 0 1 colour gunose 64 32 0
linear 0 1 colour glojaw 64 32 0
linear 0 1 colour gujaw 64 32 0
*
* get george into initial position-
*
repeat 0 1 bendby gbhead gskull ghead +20 x
repeat 0 1 bendby ghead gskull gbhead -10 x
repeat 0 1 bendby glear gjlear ghead -20 x
repeat 0 1 bendby glear gjlear ghead -20 y
repeat 0 1 bendby glear gjlear ghead -20 z
repeat 0 1 bendby grear gjrear ghead -20 x
repeat 0 1 bendby grear gjrear ghead +45 y
repeat 0 1 bendby grear gjrear ghead +20 z
repeat 0 1 bendby gforred gbrow ghead +13 x
repeat 0 1 bendby gunose gnose ghead -9 x
repeat 0 1 bendby glonose gface gunose +15 x
repeat 0 1 bendby gujaw gumouth ghead +25 x
repeat 0 1 bendby glojaw glomth ghead +8 x
repeat 0 1 bendby ghead gthroat gneck -15 x
repeat 0 1 bendby glchest glchst gshldrs -20 x
repeat 0 1 bendby grchest grchst gshldrs -20 x
repeat 0 1 bendby glthumb glpalm glhand +10 z
repeat 0 1 bendby grthumb grpalm grhand -10 z
*
***********************************************
*
figure gaina 25 *
wlfoot wrfoot wlleg wrleg wlthigh wrthigh *
wluarm wruarm wllarm wrlarm wlhand wrhand *
wlthumb wrthumb wlbrst wrbrst *
wpelvis wchest wshldrs wneck whead wnose *
whair wbun wtutu
*
ellipsoid wlfoot 40 80 20
ellipsoid wrfoot 40 80 20
ellipsoid wlleg 40 200 40
ellipsoid wrleg 40 200 40
ellipsoid wlthigh 50 200 60
ellipsoid wrthigh 50 200 60
*
ellipsoid wluarm 40 135 40
ellipsoid wruarm 40 135 40
ellipsoid wllarm 35 120 35
ellipsoid wrlarm 35 120 35
ellipsoid wlhand 40 70 20
ellipsoid wrhand 40 70 20
ellipsoid wlthumb 10 50 10
ellipsoid wrthumb 10 50 10
*
ellipsoid wlbrst 41 40 60
ellipsoid wrbrst 41 40 60
ellipsoid wpelvis 120 75 75 * l
ellipsoid wchest 130 230 75 * r
ellipsoid wshldrs 155 50 40 * l
ellipsoid wneck 30 60 30 * r
ellipsoid whead 73 100 80 * l
ellipsoid wnose 20 20 60 * r
*
ellipsoid whair 76 98 84 * l
ellipsoid wbun 50 25 50 * r
ellipsoid wtutu 300 5 300 * l
*
joint wlankle wlfoot 0 +55 0 wlleg 0 -185 0
joint wrankle wrfoot 0 +55 0 wrleg 0 -185 0
joint wlknee wlleg 0 +185 0 wlthigh 0 -175 0
joint wrknee wrleg 0 +185 0 wrthigh 0 -175 0
joint wlhip wlthigh 0 +150 0 wpelvis -60 0 0
joint wrhip wrthigh 0 +150 0 wpelvis +60 0 0
*
joint wlshldr wshldrs -145 0 0 wluarm 0 +120 0
joint wrshldr wshldrs +145 0 0 wruarm 0 +120 0
joint wlelbow wluarm 0 -115 0 wllarm 0 +100 0
joint wrelbow wruarm 0 -115 0 wrlarm 0 +100 0
joint wlwrist wllarm 0 -115 0 wlhand 0 +50 0
joint wrwrist wrlarm 0 -115 0 wrhand 0 +50 0
joint wlpalm wlhand -20 +40 +10 wlthumb 0 +40 0
joint wrpalm wrhand +20 +40 +10 wrthumb 0 +40 0
*
joint wlchest wchest -50 +100 +50 wlbrst 0 0 0
joint wrchest wchest +50 +100 +50 wrbrst 0 0 0
joint wwaist wpelvis 0 +25 0 wchest 0 -205 0
joint wthorax wchest 0 +155 0 wshldrs 0 0 0
joint wspine wshldrs 0 +40 0 wneck 0 -10 0
joint wthroat wneck 0 +20 0 whead 0 -100 0
*
joint wface whead 0 0 +55 wnose 0 0 0
joint wscalp whead 0 +6 -6 whair 0 0 0
joint wribbon whair 0 +80 -60 wbun 0 0 0
joint wbelt wchest 0 -160 0 wtutu 0 0 0
*
linear 0 1 colour wlbrst 255 0 255
linear 0 1 colour wrbrst 255 0 255
linear 0 1 colour wpelvis 255 0 255
linear 0 1 colour wchest 255 0 255
linear 0 1 colour wshldrs 255 0 255
linear 0 1 colour whair 64 32 0
linear 0 1 colour wbun 64 32 0
linear 0 1 colour wtutu 255 0 255
*
* prepare gaina (thumbs, hair, nose, feet)
* note that figure is facing away from the observer (along z axis)
* in anatomical position (palms facing forwards)
*
repeat 0 1 flex wlthumb wlpalm +10
repeat 0 1 flex wrthumb wrpalm +10
repeat 0 1 flex wbun wribbon +45
repeat 0 1 flex whair wscalp +5
repeat 0 1 flex wnose wface -30
repeat 0 1 flex wlfoot wlankle +90
repeat 0 1 flex wrfoot wrankle +90
*
***********************************************
*
variables 9 fig lfoot rfoot lleg rleg lthigh rthigh pelvis chest
variables 9 neck head nose shldrs luarm ruarm llarm rlarm lhand
variables 9 rhand lankle rankle lknee rknee lhip rhip waist thorax
variables 9 spine throat face lshldr rshldr lelbow relbow lwrist rwrist
variables 3 whiz ang nang
*
***********************************************
*
* george actions-
*
call 0 476 dogeorge
call 476 512 dogeorge * added to pad out to 512 frames
call 0 1 position
linear 0 1 grofig george world 2.2 2.2 2.2
linear 0 1 moveto george gchest 300 0 1450
linear 0 1 spinby george gchest world +152 y
*
repeat 1 26 set nang +75
repeat 1 26 set ang -45
call 1 26 raise
*
quadratic 26 51 bendby glleg glankle gpelvis +15 x
quadratic 26 51 bendby gpelvis glhip gpelvis -15 x
repeat 26 176 set whiz -360
call 26 176 piruette
quadratic 151 176 bendby gpelvis glhip gpelvis +15 x
quadratic 151 176 bendby glleg glankle gpelvis -15 x
*
call 176 284 walk
*
repeat 284 309 set ang +45
repeat 284 309 set nang -75
call 284 309 raise
*
call 309 459 point
quadratic 309 459 spinby george gchest world +30 y
*
call 459 484 courtsey
*
******************************
*
* gaina actions-
*
call 0 476 dogaina
call 0 1 position
linear 0 1 grofig gaina world 0.25 0.25 0.25
linear 0 1 moveto gaina wchest 750 0 1200
linear 0 1 spinby gaina wchest world -152 y
*
call 1 151 point
*
repeat 151 176 set nang +80
repeat 151 176 set ang -80
call 151 176 raise
*
call 176 284 walk
*
* lower arms-
*
repeat 251 276 set ang 0
repeat 251 276 set nang -80
call 251 276 raise
*
repeat 284 434 set whiz -390
call 284 434 piruette
*
* lower feet-
*
repeat 434 459 set ang +80
repeat 434 459 set nang 0
call 434 459 raise
*
call 459 484 courtsey
*
*******************************
*
* position for viewing
*
repeat 0 1 observ -10 0 0
repeat 0 1 place 500 500 500
repeat 0 1 moveby every world 0 0 500
repeat 0 512 ground george
repeat 0 512 ground gaina
*
*end main
***************************
*
subroutine position
* ( in 1 frame )
*
* lift arms somewhat-
*
repeat 0 1 flex luarm lshldr +40
repeat 0 1 flex ruarm rshldr +40
*
* bend arms roundly-
*
repeat 0 1 rotate luarm lshldr +40
repeat 0 1 rotate ruarm rshldr +40
repeat 0 1 rotate llarm lelbow +80
repeat 0 1 rotate rlarm relbow +80
*
repeat 0 1 bendby luarm lshldr shldrs -30 y
repeat 0 1 bendby ruarm rshldr shldrs +30 y
*
repeat 0 1 flex lhand lwrist +21
repeat 0 1 flex rhand rwrist +21
repeat 0 1 flex llarm lelbow +21
repeat 0 1 flex rlarm relbow +21
*
* turn legs out, placing left foot in front of right-
*
repeat 0 1 rotate lthigh lhip -80
repeat 0 1 rotate rthigh rhip -80
repeat 0 1 flex lthigh lhip +5
repeat 0 1 flex rthigh rhip -5
repeat 0 1 abduct lthigh lhip -5
repeat 0 1 abduct rthigh rhip -5
end position
*
*******************************
*
subroutine point
* ( 150 frames )
quadratic 0 25 abduct rthigh rhip +55
quadratic 0 25 flex rleg rknee +100
quadratic 0 25 flex rfoot rankle -45
*
* point right leg, and incline and turn head-
*
quadratic 25 50 flex rleg rknee -100
quadratic 25 50 bendby head throat neck -33 z
quadratic 25 50 bendby head throat neck +32 y
quadratic 25 50 flex rfoot rankle -35
*
* return to upright position-
*
quadratic 50 75 abduct rthigh rhip -55
quadratic 50 75 bendby head throat neck -32 y
quadratic 50 75 bendby head throat neck +33 z
quadratic 50 75 flex rfoot rankle +80
*
* do same for left leg-
*
quadratic 75 100 abduct lthigh lhip +55
quadratic 75 100 flex lleg lknee +100
quadratic 75 100 flex lfoot lankle -45
*
quadratic 100 125 flex lleg lknee -100
quadratic 100 125 bendby head throat neck +33 z
quadratic 100 125 bendby head throat neck -32 y
quadratic 100 125 flex lfoot lankle -35
*
quadratic 125 150 abduct lthigh lhip -55
quadratic 125 150 bendby head throat neck +32 y
quadratic 125 150 bendby head throat neck -33 z
quadratic 125 150 flex lfoot lankle +80
*
end point
************************************************
*
subroutine raise
* ( in 25 frames )
*
* on pointes-
*
quadratic 0 25 flex lfoot lankle ang
quadratic 0 25 flex rfoot rankle ang
*
* raise arms-
*
quadratic 0 25 flex ruarm rshldr nang
quadratic 0 25 flex luarm lshldr nang
*
end raise
*
*********************************
*
subroutine piruette
* ( in 125 frames )
*
quadratic 1 26 flex ruarm rshldr +50
quadratic 1 26 flex luarm lshldr +40
quadratic 26 50 bendby luarm lshldr shldrs -90 y
quadratic 1 26 bendby head throat neck -30 x
quadratic 1 26 bendby chest waist pelvis +20 x
quadratic 1 26 flex rthigh rhip -90
quadratic 1 26 bendby pelvis lhip pelvis -5 x
quadratic 1 26 spinby fig lfoot pelvis +5 x
*
decelerate 26 150 spinby fig lfoot world whiz y
*
quadratic 126 150 spinby fig lfoot pelvis -5 x
quadratic 126 150 bendby pelvis lhip pelvis +5 x
quadratic 126 150 flex rthigh rhip +90
quadratic 126 150 bendby chest waist pelvis -20 x
quadratic 126 150 bendby head throat neck +30 x
quadratic 101 126 bendby luarm lshldr shldrs +90 y
quadratic 126 150 flex luarm lshldr -40
quadratic 126 150 flex ruarm rshldr -50
*
end piruette
********************************
*
subroutine courtsey
* ( in 25 frames )
quadratic 1 26 flex ruarm rshldr -30
quadratic 1 26 bendby ruarm rshldr shldrs +60 y
quadratic 1 26 bendby luarm lshldr shldrs -70 y
quadratic 1 26 bendby head throat neck +60 x
quadratic 1 26 bendby lleg lankle lfoot +40 x
quadratic 1 26 bendby lthigh lknee lfoot -80 x
quadratic 1 26 bendby pelvis lhip lfoot +40 x
quadratic 1 26 bendby chest waist pelvis +50 x
quadratic 1 26 flex rthigh rhip -30
quadratic 1 26 flex rleg rknee +30
end courtsey
*
*****************************
*
subroutine dogeorge
repeat 0 476 set fig george
repeat 0 476 set lfoot glfoot
repeat 0 476 set rfoot grfoot
repeat 0 476 set lleg glleg
repeat 0 476 set rleg grleg
repeat 0 476 set lthigh glthigh
repeat 0 476 set rthigh grthigh
repeat 0 476 set pelvis gpelvis
repeat 0 476 set chest gchest
repeat 0 476 set neck gneck
repeat 0 476 set head ghead
repeat 0 476 set nose gnose
repeat 0 476 set shldrs gshldrs
repeat 0 476 set luarm gluarm
repeat 0 476 set ruarm gruarm
repeat 0 476 set llarm gllarm
repeat 0 476 set rlarm grlarm
repeat 0 476 set lhand glhand
repeat 0 476 set rhand grhand
*
repeat 0 476 set lankle glankle
repeat 0 476 set rankle grankle
repeat 0 476 set lknee glknee
repeat 0 476 set rknee grknee
repeat 0 476 set lhip glhip
repeat 0 476 set rhip grhip
repeat 0 476 set waist gwaist
repeat 0 476 set thorax gthorax
repeat 0 476 set spine gspine
repeat 0 476 set throat gthroat
repeat 0 476 set face gface
repeat 0 476 set lshldr glshldr
repeat 0 476 set rshldr grshldr
repeat 0 476 set lelbow glelbow
repeat 0 476 set relbow grelbow
repeat 0 476 set lwrist glwrist
repeat 0 476 set rwrist grwrist
end dogeorge
********************************
*
subroutine dogaina
repeat 0 476 set fig gaina
repeat 0 476 set lfoot wlfoot
repeat 0 476 set rfoot wrfoot
repeat 0 476 set lleg wlleg
repeat 0 476 set rleg wrleg
repeat 0 476 set lthigh wlthigh
repeat 0 476 set rthigh wrthigh
repeat 0 476 set pelvis wpelvis
repeat 0 476 set chest wchest
repeat 0 476 set neck wneck
repeat 0 476 set head whead
repeat 0 476 set nose wnose
repeat 0 476 set shldrs wshldrs
repeat 0 476 set luarm wluarm
repeat 0 476 set ruarm wruarm
repeat 0 476 set llarm wllarm
repeat 0 476 set rlarm wrlarm
repeat 0 476 set lhand wlhand
repeat 0 476 set rhand wrhand
*
repeat 0 476 set lankle wlankle
repeat 0 476 set rankle wrankle
repeat 0 476 set lknee wlknee
repeat 0 476 set rknee wrknee
repeat 0 476 set lhip wlhip
repeat 0 476 set rhip wrhip
repeat 0 476 set waist wwaist
repeat 0 476 set thorax wthorax
repeat 0 476 set spine wspine
repeat 0 476 set throat wthroat
repeat 0 476 set face wface
repeat 0 476 set lshldr wlshldr
repeat 0 476 set rshldr wrshldr
repeat 0 476 set lelbow wlelbow
repeat 0 476 set relbow wrelbow
repeat 0 476 set lwrist wlwrist
repeat 0 476 set rwrist wrwrist
end dogaina
*
*****************************
*
subroutine step
*
* take a step in 12 frames
*
quadratic 0 6 bendby lleg lankle pelvis +16 x
quadratic 0 6 bendby pelvis lhip pelvis -16 x
quadratic 0 6 flex rthigh rhip +16
quadratic 0 6 bendby rfoot rankle pelvis +16 x
*
quadratic 6 12 bendby rleg rankle pelvis +16 x
quadratic 6 12 bendby pelvis rhip pelvis -16 x
quadratic 6 12 flex lthigh lhip +16
quadratic 6 12 bendby lfoot lankle pelvis +16 x
*
end step
*
*****************************
*
subroutine hrstep
*
* take half a step starting on the left foot in 6 frames
*
quadratic 0 6 bendby rleg rankle pelvis +8 x
quadratic 0 6 bendby pelvis rhip pelvis -8 x
quadratic 0 6 flex lthigh lhip +8
quadratic 0 6 bendby lfoot lankle pelvis +8 x
*
end hrstep
*
********************************
*
subroutine hlstep
*
* take half a step starting on the right foot in 6 frames
*
quadratic 0 6 bendby lleg lankle pelvis +8 x
quadratic 0 6 bendby pelvis lhip pelvis -8 x
quadratic 0 6 flex rthigh rhip +8
quadratic 0 6 bendby rfoot rankle pelvis +8 x
*
end hlstep
*
********************************
*
subroutine walk
*
* ( in 108 frames )
*
call 0 6 hrstep
call 6 18 step
call 18 30 step
call 30 42 step
call 42 54 step
call 54 66 step
call 66 78 step
call 78 90 step
call 90 102 step
call 102 108 hlstep
end walk
*
*****************************
*
stop